Skip to end of metadata
Go to start of metadata

Step 2: Modify Log file - part 1

Delete Special Commands

We'll start by deleting unnecessary commands. ANSYS generates certain commands which are either generated by default or intended for use in Batch mode (i.e. no user interface). Since we are not going be working in batch mode, we will ignore the following commands. Delete the following commands:

/BATCH
/input,menust,tmp,'',,,,,,,,,,,,,,,,1
WPSTYLE,,,,,,,,0
/NOPR
/PMETH,OFF,0

The next eleven commands in the original input file start with KEYW. This set of commands customizes the graphical user interface. Since we are not going be using the graphical user interface, we'll ignore these commands. Delete commands that start with KEYW.

Modify Specified Parameters

We'll now modify the parameters specified in the Plate with a Hole tutorial. We'll do so by modifying the commands that start with *SET. The scalar parameters created as part of the Plate with a Hole tutorial are the plate half-width a, hole radius r, applied pressure p, and material properties E and n. We will redefine these parameters and add new ones to match the geometry and material properties of our problem:

*SET,a,60e-3
*SET,r,7e-3
*SET,p,1e6
*SET,E1,59.3e9
*SET,E2,22e9
*SET,G12,8.96e9
*SET,nu21,0.047

Note that the plate half-width a changed from 10e^-3^ to 60e^-3^ and the hole radius rremained unchanged. Also, the material properties were modified to include the orthotropic material properties: Young's modulus in the fiber direction E1=Ex=59.3GPa, Young's modulus in the transverse direction E2=Ey=22 GPa, in-plane shear modulus G12=Gxy =8.9GPa and minor Poisson ratio nu21=0.047.

At this point, the modified input file should be as follows:

/Title, Orthotropic Plate with a Hole
*SET,a,60e-3
*SET,r,7e-3
*SET,p,1e6
*SET,E1,59.3e9
*SET,E2,22e9
*SET,G12,8.96e9
*SET,nu21,0.047

Note that the /Title, Orthotropic Plate with a Hole command has been added. This command allows us to add a title which will be shown in the various user interface windows.

Specify Element Type

Before specifying the element type, we need to enter the model creator preprocessor. This is equivalent to entering the preprocessor tab in the ANSYS Main Menu. The following command, which was part of the original input file, accomplishes this task and we'll keep it for our analysis.

/PREP7

The ET command defines the element type. For the Plate with a Hole tutorial, we used PLANE42, which is a 4-node 2D structural solid element. For this tutorial, we will use PLANE82, which is a 8-node 2-D structural solid element.

ET,1,PLANE82

Specify Material Properties

The next set of commands in the original file, specify the material properties by using MPTEMP and MPDATA. For our analysis, however, we will use the MP command instead. We'll also use the previously defined parameters.

MP,EX,1,E1
MP,EY,1,E2
MP,NUXY,1,NU21
MP,GXY,1,G12

Note that we have added two more commands: MP,EY,1,E2 and MP,GXY,1,G12. These define the Young's modulus in the transverse direction and the in-plane shear modulus, respectively. Also, note that we have specified the minor Poisson ratio rather than the major Poisson ratio by using the MP,NUXY command.

Create Geometry

The next set of commands in the original file, generate the geometry by creating a square area of side a and then subtracting a circular sector of radius r. Since the geometry we want to generate is the same, we will use the same set of commands. In addition, since the geometry, material properties and loading of our problem are also all symmetric with respect to the horizontal and vertical centerlines, we will model only a quarter of the plate.

RECTNG,0,a,0,a,
CYL4,0,0,0,0,r,90
ASBA,1,2

Note that the list of commands is the same. The fact that we changed the value for the plate half-width when we modified the parameters, allows us to keep the same list of commands to create the desired geometry.

At this point, the modified log file should be as follows:

/Title, Orthotropic Plate with a Hole
*SET,a,60e-3
*SET,r,7e-3
*SET,p,1e6
*SET,E1,59.3e9
*SET,E2,22e9
*SET,G12,8.96e9
*SET,nu21,0.047
/PREP7
ET,1,PLANE82
MP,EX,1,E1
MP,EY,1,E2
MP,NUXY,1,NU21
MP,GXY,1,G12
RECTNG,0,a,0,a,
CYL4,0,0,0,0,r,90
ASBA,1,2

Verify Progress

Let's verify the list of commands we created have so far. To do this, you will need to start a new ANSYS session. Restart ANSYS or go to Utility Menu > File > Clear & Start New and select Do not read file (if you have been working on another file).

Copy the list of commands we have generated so far and paste them in the ANSYS Command Input window.


The list of commands will generate the following.


 
Next, we will continue to modify the original file to mesh the areas and specify boundary conditions.

Go to Step 3: Modify log file - part 2

Go to all ANSYS Learning Modules

  • No labels